#?debug: "list_variable=1, show_failure=1, trace_rank=[1.1.1]"

?option: "wrap=1, year_offset=-9:0"

=$難星:		{$難宮}
=$仇星:		{$仇宮}
=$恩星:		{$恩宮}
=$用星:		{$用宮}

# 命盤
{?t}:
{(&iter($七政, "{&星力([])}"), $e)}\
{$s}立命{@命[0]}宮{%命}度，安身{@身[0]}宮{$命身歧}。{$難星}為難，{$仇星}為仇，{$恩星}為恩，{$用星}為用。
{$s&if( \
	"{(%命[1]=@命[1] & %命[1]=@身[1])}", "{&力解(%命[1], {命度、命宮、身宮主%命[1]})}", \
	"{(%命[1]=@命[1])}", "{&力解(%命[1], {命度、命宮主%命[1]}) &力解(@身[1], {身宮主@身[1]})}", \
	"{(%命[1]=@身[1])}", "{&力解(%命[1], {命度、身宮主%命[1]}) &力解(@命[1], {命宮主@命[1]})}", \
	"{(@命[1]=@身[1])}", "{&力解(%命[1], {命度主%命[1]}) &力解(@命[1], {身命宮主@命[1]})}", \
	"{&力解(%命[1], {命度主%命[1]}) &力解(@命[1], {命宮主@命[1]}) &力解(@身[1], {身宮主@身[1]})}" \
)}

{&if(@命=@身, "{$s&命坐(身命)}", "{$s&命坐(命)$n$s$身宮神煞}")}

{&宮解(福德)}
{&宮解(財帛)}
{&宮解(官祿)}
{&宮解(田宅)}
{&宮解(夫妻)}
{&宮解(男女)}

$


# user defined functions
=&升殿:		{&if(?[a]殿, "{([a]力解+<升殿, [a]力+=1)}")} 
=&失躔:		{&if(?[a]失躔, "{([a]力解+<失躔, [a]力-=1)}")} 
=&入垣:		{&if(?[a]垣, "{([a]力解+<入垣, [a]力+=1)}")} 
=&失垣:		{&if(?[a]失垣, "{([a]力解+<失垣, [a]力-=1)}")} 
=&季星:		{&if([a]=$季星, "{([a]力解+<為季星, [a]力+=1)}")}
=&化星:		{&if(??[a]化, "{化{$[a]化}}")}
=&星力:		{(&升殿([a]), &失躔([a]), &入垣([a]), &失垣([a]), &季星([a]), \
			&生剋星同度([a]), &生剋星同宮([a]), &生剋星對宮([a]), &生剋星拱宮([a]), \
			&if(??[a]力, "$[a]力", 0))}
=&力解:		{&if(??[a]力解, "{[b]，{$[a]力解}。}")}

=&化星照:	{&if(*[a]宮星, {{&iter($[a]宮星, "{$難恩[]&化星([])}")}照[a]。})}
=&神煞臨:	{&if(*[a]宮神|*[a]宮煞, {{$[a]宮神}&if(*[a]宮神&*[a]宮煞, ，){$[a]宮煞}入宮。})}
=&宮解:		{$s{[a]宮{&神煞臨([a])}{&if(*[a]宮星, "{&化星照([a])}")}}}
=$命身歧:	{&if("?命宮歧&?命宿歧", ，命坐宮歧、宿歧, "?命宮歧", ，命坐宮歧, "?命宿歧", ，命坐宿歧) \
			&if(?身宮歧, "&if(?命宮歧&?命宿歧, ，身坐宮歧, 身坐宮歧)")}

=&生剋星:	{&prefix(&prefix([a], $[b]生星, 生星), $[b]剋星, 剋星)}
=&{生, 剋}星同宮:	{&intersection(${{@[a][0]}宮星}, $[a]{}星)}
=&{生, 剋}星同度:	{&intersection(${{%[a][0]}度星}, $[a]{}星)}
=&{生, 剋}星對宮:	{&intersection(${{(@[a]+6)[0]}宮星}, $[a]{}星)}
=&{生, 剋}星拱宮:	{&intersection(&union(${{(@[a]+4)[0]}宮星}, ${{(@[a]-4)[0]}宮星}), $[a]{}星)}

=&生剋星同宮:	{(_a<<&生星同宮([a]), _b<<&剋星同宮([a]), &if(*_a | *_b, \
			"{([a]力解+<{&宮度始([a])&if(*_a, {生星$_a})&if(*_b, {剋星$_b})同宮}, [a]力+=&size($_a) - &size($_b))}"))}
=&生剋星同度:	{(_a<<&生星同度([a]), _b<<&剋星同度([a]), &if(*_a | *_b, \
			"{([a]力解+<{&宮度始([a])&if(*_a, {生星$_a})&if(*_b, {剋星$_b})同度}, [a]力+=&size($_a) - &size($_b))}"))}
=&生剋星對宮:	{(_a<<&生星對宮([a]), _b<<&剋星對宮([a]), &if(*_a | *_b, \
			"{([a]力解+<{&if(*_a, {生星$_a})&if(*_b, {剋星$_b})對照}, [a]力+=0.7 * (&size($_a) - &size($_b)))}"))}
=&生剋星拱宮:	{(_a<<&生星拱宮([a]), _b<<&剋星拱宮([a]), &if(*_a | *_b, \
			"{([a]力解+<{&if(*_a, {生星$_a})&if(*_b, {剋星$_b})拱照}, [a]力+=0.3 * (&size($_a) - &size($_b)))}"))}
=&宮度始:	{&if(!??[a]宮度始, "{([a]宮度始<<1, 與)}")}
=&命坐:		{&if(*命坐地, "{[a]坐{$命坐地}，}"){[a]宮&神煞臨(命)}{&if(*命宮星, "{$化星守命}")}}

# aliases
=$七政:		{&set(日, 月, 金, 木, 水, 火, 土)}
=$四餘:		{&set(計, 羅, 炁, 孛)}
=$政餘:		{&union($七政, $四餘)}
=${日, 月, 金, 木, 水, 火, 土, 計, 羅, 炁, 孛}帶神煞:	\
		{&eval(&contain($宮位, {})[0], 宮神煞)}
=$難恩{日, 月, 金, 木, 水, 火, 土, 計, 羅, 炁, 孛}:	\
		{&prefix(&prefix({}, $難星, 難), $恩星, 恩)}
=$難仇恩用{日, 月, 金, 木, 水, 火, 土}:	\
		{&import(難仇恩用{})}
=${日, 月, 金, 木, 水, 火, 土}剋星:	\
		{&split(&entry(${難仇恩用{}}, 0), 1)}
=${日, 月, 金, 木, 水, 火, 土}生星:	\
		{&split(&entry(${難仇恩用{}}, 2), 1)}
=${計, 羅, 炁, 孛}剋星:	\
		{$e}
=${計, 羅, 炁, 孛}生星:	\
		{$e}
=$季節星:	{&set(木炁, 火羅, 金, 水孛)}
=$季星:		{&split(&entry($季節星, $季節), 1)}
=$身命:		{&if(@命=@身, 身命, 命)}
=${命, 身, 財帛, 兄弟, 田宅, 男女, 奴僕, 夫妻, 疾厄, 遷移, 官祿, 福德, 相貌}宮星:	\
		{${{@{}[0]}宮星}}
=$化星守命:	{&if(*命宮星, {{&iter($命宮星, "{$難恩[]&化星([])}")}守{$身命}。})}
=$化星臨身:	{&if(*身宮星, {{&iter($身宮星, "{$難恩[]&化星([])}")}臨身。})}
=${命, 身, 財帛, 兄弟, 田宅, 男女, 奴僕, 夫妻, 疾厄, 遷移, 官祿, 福德, 相貌}宮神:	\
		{&intersection(${{@{}[0]}宮神煞}, $吉神, 4)}
=${命, 身, 財帛, 兄弟, 田宅, 男女, 奴僕, 夫妻, 疾厄, 遷移, 官祿, 福德, 相貌}宮煞:	\
		{&intersection(${{@{}[0]}宮神煞}, $凶煞, 4)}
=$身宮神煞:	{{&if(*身坐地, "{身坐{$身坐地}，}")身宮坐${{@身[0]}宮}，&神煞臨(身)}{&if(*身宮星, "{$化星臨身}")}}
=${命, 身}坐地:	{&map(&intersection(${{@{}[0]}宮神煞}, $長生), 註)}	
=$長生:		{&set(長生, 絕, 死, 病, 帝旺, 臨官, 沐浴)}
=${絕, 死, 病, 帝旺=旺}註:	\
		{}地
=$吉神:		{&set(紅鸞, 祿勳, 唐符, 咸池, 天貴, 斗杓, 喜神, 文昌, 卦氣, 玉貴, \
			天喜, 國印, 驛馬, 紫微, 天德)}
=$凶煞:		{&set(病符, 寡宿, 劫殺, 絞殺, 飛刃, 天狗, 陽刃, 陰刃, 天耗, 劍鋒, \
			孤辰, 孤虛, 飛廉, 天雄, 大耗, 小耗, 闌干, 血刃, 空亡, 的殺)}
=$流吉神:	{&set(天喜, 紅鸞, 驛馬, 天廚, 咸池, 祿勳, 天德, 天貴, 地解, 解神)}
=$流凶煞:	{&set(歲駕, 天空, 地雌, 貫索, 五鬼, 死符, 大耗, 小耗, 陽刃, 陰刃, 天厄, \
			天雄, 大殺, 卷舌, 天狗, 驀越, 亡神, 披頭, 血刃, 天哭, 劫殺, \
			的殺, 黃幡, 豹尾, 三刑, 六害)}

#
# rules with '^' are dynamic, they are reset after each year
#

# 流年盤
{?t}:^
{$流年}年{$流歲}歲, 流年{$流年柱}, 小限在{$小限}, 限行{$限宮}宮{$限度}度:
{$s2{$小限宮名}{$難恩宮}{$限煞入宮}。}
{$行限度}
$

=$行限度:^	{&iter($限度, "{&行限度([])}", $e)}
=&行限度:^	{(&iter($政餘, "{&同限度([], [a])}"), &iter($政餘, "{&衝限度([], [a])}"), \
			&iter($政餘, "{&刑限度([], [a])}"), &iter($政餘, "{&合限度([], [a])}"), \
			&限度解([a]), &if(??[a]度解, "{{$s2}限行{[a]}度，{$[a]度解}。$n}"))}
=&同限度:^	{&if([b]=%[a], "([b]同限解+<{&生剋星([a], [b][1])})")}
=&衝限度:^	{&if(&offset($限度度, $[a]度, 180, 6 + $限度角距), "([b]衝限解+<{&生剋星([a], [b][1])})")}
=&刑限度:^	{&if(&offset($限度度, $[a]度, 90, 3 + $限度角距), "([b]刑限解+<{&生剋星([a], [b][1])})")}
=&合限度:^	{&if(&offset($限度度, $[a]度, 120, 4 + $限度角距), "([b]合限解+<{&生剋星([a], [b][1])})")}
=&限度解:^	{(&if(??[a]同限解, "([a]度解+<{{$[a]同限解}同躔})"), \
			&if(??[a]衝限解, "([a]度解+<{{$[a]衝限解}衝})"), \
			&if(??[a]刑限解, "([a]度解+<{{$[a]刑限解}刑})"), \
			&if(??[a]合限解, "([a]度解+<{{$[a]合限解}合})"))}


# 流年 aliases
=$小限宮名:^	{&if(&empty(&contain($小限宮, 宮)), {{$小限宮}宮}, $小限宮)}
=$小限宮:^	{${${小限}宮}}
=$小限神煞:^	{${流${小限}宮神煞}}
=$限神:^	{&intersection($小限神煞, $流吉神, 4)}
=$限煞:^	{&intersection($小限神煞, $流凶煞, 4)}
=$限煞入宮:^	{&if(*限煞|*限神, {{&if(*限神, {流年吉神{$限神}})}{&if(*限煞&*限神, ，)}{&if(*限煞, {流年凶煞{$限煞}入宮})}})}
=$難恩宮:^	{&if("@{$小限宮}[1]=$難星", 為難宮，, "@{$小限宮}[1]=$恩星", 為恩宮，)}