// Globals
$puts(indent,$repeat( ,5))
$puts(title_color,232323)
$puts(field_color,323232)
$puts(field_color_dull,656565)

// Progress bar
$puts(prog_bar_color1,$get(title_color))
$puts(prog_bar_color2,FFFFFF)
$puts(prog_bar_color3,$get(field_color))
$puts(prog_bar_color4,454545)

$puts(prog_bar_len,55)
$puts(prog_bar_char1,|)
$puts(prog_bar_char2,:)


//Info
$char(1)R[808080%_trackinfo_mode% mode$char(10)]

// SEPERATOR
$char(1)C$get(title_color)···$char(10)

// MAIN INFO
$if(%artist%,
$get(title_color)ARTIST$char(10)
$get(indent)$get(field_color)[%artist%]$char(10))

$if(%album%,
$get(title_color)ALBUM$char(10)
$get(indent)$get(field_color)[%album%][ - CD%DISC%]$char(10))

$if(%title%,
$get(title_color)TITLE$char(10)
$get(indent)$get(field_color)[%title%]$char(10))

$if(%tracknumber%,
$get(title_color)TRACK NUMBER$char(10)
$get(indent)$get(field_color)[$num(%tracknumber%,1)]$char(10))

$if(%genre%,
$get(title_color)GENRE$char(10)
$get(indent)$get(field_color)[%genre%]$char(10))

$if(%date%,
$get(title_color)RELEASE YEAR$char(10)
$get(indent)$get(field_color)[%date%]$char(10))
$char(10)

$if(%_isplaying%,
$get(title_color)TIME$char(10)
$get(indent)$get(field_color)'('$get(field_color_dull)-%_time_remaining%$get(field_color)')'   %_time_elapsed% / %_length%   -   $muldiv(%_time_elapsed_seconds%, 100, %_time_total_seconds%)'%'
$char(10)$get(indent)$get(prog_bar_color1)'['$get(prog_bar_color2)$progress(%_time_elapsed_seconds%, %_time_total_seconds%, $get(prog_bar_len),$get(prog_bar_color3)$get(prog_bar_char1)$get(prog_bar_color4),$get(prog_bar_char2))$get(prog_bar_color1)']'
,
$get(title_color)LENGTH$char(10)
$get(indent)$get(field_color)[%_length%]
)$char(10)

$char(10)


$if($or(%__replaygain_track_gain%,%__replaygain_album_gain%),
$if(%__replaygain_track_gain%,$get(title_color)REPLAYGAIN TRACK$char(10)
$get(indent)$get(field_color)[%__replaygain_track_gain% '('$get(field_color_dull)Peak: %__replaygain_track_peak%$get(field_color)')']$char(10),
)

$if(%__replaygain_album_gain%,$get(title_color)REPLAYGAIN ALBUM$char(10)
$get(indent)$get(field_color)[%__replaygain_album_gain%  '('$get(field_color_dull)Peak: %__replaygain_album_peak%$get(field_color)')']$char(10),
)
$char(10)
)
// REPLAYGAIN


// FILE INFO

// CODEC
$get(title_color)CODEC$char(10)
$get(indent)$get(field_color)[%__codec%]$if(%__lame_version%, '('$get(field_color_dull)%__lame_version%$get(field_color)')',)$char(10)

// BITRATE
$get(title_color)BITRATE$char(10)
$get(indent)$get(field_color)[$if2(%__bitrate_dynamic%,%__bitrate%)$if($stricmp(%__codec%,mp3),$if(%__extrainfo%, %__extrainfo%, CBR))$if(%__lame_profile%,'  ('$get(field_color_dull)%__lame_profile%$get(field_color)')',)]$char(10)

// SAMEPLRATE
$get(title_color)SAMPLERATE$char(10)
$get(indent)$get(field_color)[%__samplerate%Hz]$char(10)

// CHANNELS
$get(title_color)CHANNELS$char(10)
$get(indent)$get(field_color)$if2($caps(%__mp3_stereo_mode%),$select(%__channels%,Mono,Stereo,2.1,3.1,4.1,5.1,6.1,7.1))$char(10)

// RIP TYPE
$if($strcmp(%__codec%,MP3),
$get(title_color)RIP TYPE$char(10)
$get(indent)$get(field_color)$if(%__mp3_accurate_length%,CD Rip,Transcode)$char(10)
)
$char(10)


// FILE NAME
$get(title_color)FILENAME$char(10)
$get(indent)$get(field_color)%_filename_ext%$char(10)

// FILE SIZE
$get(title_color)FILESIZE$char(10)
$get(indent)$get(field_color)$div(%_filesize%,1048576).$num($muldiv($mod(%_filesize%,1048576),100,1048576),2) MB