A common use for a macro is to perform a series of search and replace operations throughout a document to correct or change formatting or text. Macros are ideally suited to this sort of repetitious task. There are two good methods you can use within a macro, depending on the exact changes you are making.
Simple Search/Replace
If you need to do a series of simple Search and Replaces, you can use the code shown below.
Application (WordPerfect; "WordPerfect"; Default!; "EN")
PosDocTop ()
SearchString (StrgToLookFor: "The first thing")
ReplaceString (RplcStrg: "first replace string")
ReplaceForward (SearchMode: Extended!)
PosDocTop ()
SearchString (StrgToLookFor: "The second thing")
ReplaceString (RplcStrg: "second replace string")
ReplaceForward (SearchMode: Extended!)
PosDocTop ()
SearchString (StrgToLookFor: "The third thing:")
ReplaceString (RplcStrg: "third replace string")
ReplaceForward (SearchMode: Extended!)
PosDocTop ()
To include additional search and replace operations, just copy one of the sets of search and replace commands, and replace the search and replace strings. You can include as many sets of commands as needed.
I've used this method in a macro I created to clean up dialog code that is pasted from the Dialog Editor. I really don't like all the parameter names cluttering up my code, so I run this macro after pasting a dialog initially created in the DE.
In all cases, the replace string is a blank string, so I use the FORNEXT command to simplify the multiple search and replaces I needed to do in this macro.
Application (WordPerfect; "WordPerfect"; Default!; "EN")
EditCut ()
FileNew ()
EditPaste ()
PosDocTop ()
FOREACH(x; {"Dialog:";"Control:";"Left:";
"Top:";"Width:";"Height:";"ButtonText:";
"Style:";"MacroVar:";"Caption:";"Fontname:";
"Fontsize:";"Text:"})
SearchString (StrgToLookFor:x)
ReplaceString (RplcStrg: "")
ReplaceForward (SearchMode: Extended!)
PosDocTop ()
ENDFOR
SelectAll ()
EditCut ()
DocNext ()
EditPaste ()
To run this macro, first paste your dialog code (see the June 1997 back issue if you don't know what I am talking about here). Next, select the dialog code that was just pasted, then run this macro. All the extraneous parameter names will be removed.
Complex Search and Text Manipulation
If you are using Search, then performing some other action, you macro code will be a bit more complex. Normally, if a search fails, the macro will simply terminate. PerfectScript includes commands to test for the Not Found condition, and we need to do checking for this condition for each search so that we can send execution to the next search.
The sample code below shows how to perform multiple searches in the same macro.
vCounter:=0 // initialize the search counter
vLastSearch:=3 // set total number of searches
OnNotFound(top) // When NotFound condition occurs, go to Label(top)
Label(top)
PosDocTop() // Go to top of document
vCounter:=vCounter+1 // increment counter by 1
If(vCounter>vLastSearch) // if the new counter value is greater than
MessageBox(; ; "Done!") // the number of searches
Quit // end macro
Else // otherwise
G0(Indirect("Search"+vCounter)) // go to next search label
Endif
Label(Search1) // first search
SearchString("the first thing")
SearchNext()
// do some operation
Go(Search1) // loop until Not Found
Label(Search2) // second search
SearchString("the second thing")
SearchNext()
// do some operation
Go(Search2) // loop until Not Found
Label(Search3) // third search
SearchString("the third thing")
SearchNext()
// do some operation
Go(Search3) // loop until Not Found
You can include as many searches as necessary in this macro by changing the value of vLastSearch, and including a Label with the appropriate search commands, and the commands for the other operations you want to perform.
