//*******Use Bard Specific Items*******//

//***Bardic Horn of Valhalla***//

//Use the Horn
IF                                                                         
	ActionListEmpty()                                                     
	HasItem("BARDIC",Myself)
	Class(Myself,BARD)                                       
	Global("gr_Used_BHoV","LOCALS",0)
	OR(2)
	  NumCreatureGT([ENEMY],4)
	  HPGT(NearestEnemyOf(Myself),80)
	NumCreatureLT([GOODCUTOFF.0.0.0.0.SUMMONED],5)                          
THEN                                                                       
  RESPONSE #100                                                            
    SetGlobalTimer("gr_BHoV_Recharge_Timer","LOCALS",EIGHT_HOURS)
    SetGlobal("gr_Used_BHoV","LOCALS",1)                
    UseItem("BARDIC",Myself)                                               
END 

//If the Horn is recharged, allow it to be used again
IF
	OR(2)
	  GlobalTimerExpired("gr_BHoV_Recharge_Timer","LOCALS")
	  PartyRested()
	Global("gr_Used_BHoV","LOCALS",1)
THEN
	RESPONSE #100                                                            
		SetGlobal("gr_Used_BHoV","LOCALS",0)                                            
END 

//***The Merry Shorthorn***//

//Use the Shorthorn
IF                                                                         
	ActionListEmpty()                                                     
	HasItem("MHORN",Myself)
	Class(Myself,BARD)                                        
	Global("gr_Used_Merry_Shorthorn","LOCALS",0)
	!StateCheck(Myself,STATE_AID)
	!StateCheck(Myself,STATE_BLESS)
	!StateCheck(Myself,STATE_CHANT)                         
THEN                                                                       
  RESPONSE #100                                                            
    SetGlobalTimer("gr_Merry_Shorthorn_Timer","LOCALS",EIGHT_HOURS)
    SetGlobal("gr_Used_Merry_Shorthorn","LOCALS",1)                
    UseItem("MHORN",Myself)                                               
END 

//If the Shorthorn is recharged, allow it to be used again
IF
	OR(2)
	  GlobalTimerExpired("gr_Merry_Shorthorn_Timer","LOCALS")
	  PartyRested()
	Global("gr_Used_Merry_Shorthorn","LOCALS",1)
THEN
	RESPONSE #100                                                            
		SetGlobal("gr_Used_Merry_Shorthorn","LOCALS",0)                                            
END 

//***Viol of the Hollow Men***//

//Use the Viol
IF                                                                         
	ActionListEmpty()                                                     
	HasItem("VIOLIN",Myself)
	Class(Myself,BARD)                                        
	Global("gr_Used_VotHM","LOCALS",0)
	OR(2)
	  NumCreatureGT([ENEMY],4)
	  HPGT(NearestEnemyOf(Myself),80)
	NumCreatureLT([GOODCUTOFF.0.0.0.0.SUMMONED],5)                          
THEN                                                                       
  RESPONSE #100                                                            
    SetGlobalTimer("gr_VotHM_Recharge_Timer","LOCALS",EIGHT_HOURS)
    SetGlobal("gr_Used_VotHM","LOCALS",1)                
    UseItem("VIOLIN",Myself)                                               
END 

//If the Viol is recharged, allow it to be used again
IF
	OR(2)
	  GlobalTimerExpired("gr_VotHM_Recharge_Timer","LOCALS")
	  PartyRested()
	Global("gr_Used_VotHM","LOCALS",1)
THEN
	RESPONSE #100                                                            
		SetGlobal("gr_Used_VotHM","LOCALS",0)                                            
END 

//***The Cittern of War***//

//Use the Cittern
IF                                                                         
	ActionListEmpty()                                                     
	HasItem("CITTERN",Myself)
	Class(Myself,BARD)                                         
	Global("gr_Used_Cittern_of_War","LOCALS",0)
	!StateCheck(Myself,STATE_AID)
	!StateCheck(Myself,STATE_BLESS)
	!StateCheck(Myself,STATE_CHANT)                         
THEN                                                                       
  RESPONSE #100                                                            
    SetGlobalTimer("gr_Cittern_of_War_Timer","LOCALS",EIGHT_HOURS)
    SetGlobal("gr_Used_Cittern_of_War","LOCALS",1)                
    UseItem("CITTERN",Myself)                                               
END 

//If the Cittern is recharged, allow it to be used again
IF
	OR(2)
	  GlobalTimerExpired("gr_Cittern_of_War_Timer","LOCALS")
	  PartyRested()
	Global("gr_Used_Cittern_of_War","LOCALS",1)
THEN
	RESPONSE #100                                                            
		SetGlobal("gr_Used_Cittern_of_War","LOCALS",0)                                            
END 

//***The Unstrung Harp***//

//Use the Harp
IF                                                                         
	ActionListEmpty()                                                     
	HasItem("HARP",Myself)
	Class(Myself,BARD)
	!Alignment(Myself,MASK_EVIL)
	CheckStatGT(Myself,12,WIS)
	Global("gr_Used_Unstrung_Harp","LOCALS",0)
	HPPercentLT(MostDamagedOf(),25)
	CheckStatGT(MostDamagedOf(),29,MAXHITPOINTS)
THEN                                                                       
  RESPONSE #100                                                            
    SetGlobalTimer("gr_Unstrung_Harp_Timer","LOCALS",EIGHT_HOURS)
    SetGlobal("gr_Used_Unstrung_Harp","LOCALS",1)                
    UseItem("HARP",MostDamagedOf())                                               
END 

//If the Harp is recharged, allow it to be used again
IF
	OR(2)
	  GlobalTimerExpired("gr_Unstrung_Harp_Timer","LOCALS")
	  PartyRested()
	Global("gr_Used_Unstrung_Harp","LOCALS",1)
THEN
	RESPONSE #100                                                            
		SetGlobal("gr_Used_Unstrung_Harp","LOCALS",0)                                            
END 

//***The Dire Old Lute of Pellon Kay***//

//Use the Lute
IF                                                                         
    ActionListEmpty()                                                     
    HasItem("PELLON",Myself)
    Class(Myself,BARD)                                         
    Global("gr_Used_Dire_Lute","LOCALS",0)
    !StateCheck(NearestEnemyOf(Myself),STATE_PANIC)
    !StateCheck(NearestEnemyOf(Myself),STATE_FEEBLEMINDED)
    !StateCheck(NearestEnemyOf(Myself),STATE_CONFUSED)
    !StateCheck(NearestEnemyOf(Myself),STATE_SLEEPING)
    !StateCheck(NearestEnemyOf(Myself),STATE_HELPLESS)
    !StateCheck(NearestEnemyOf(Myself),STATE_STUNNED)
    !StateCheck(NearestEnemyOf(Myself),STATE_CHARMED)
    !StateCheck(NearestEnemyOf(Myself),STATE_BLIND)
    !StateCheck(NearestEnemyOf(Myself),STATE_SLOWED)                        
THEN                                                                       
  RESPONSE #100                                                            
    SetGlobalTimer("gr_Dire_Lute_Recharge_Timer","LOCALS",EIGHT_HOURS)
    SetGlobal("gr_Used_Dire_Lute","LOCALS",1)                
    UseItem("PELLON",NearestEnemyOf(Myself))                                               
END 

//If the Lute is recharged, allow it to be used again
IF
	OR(2)
	  GlobalTimerExpired("gr_Dire_Lute_Recharge_Timer","LOCALS")
	  PartyRested()
	Global("gr_Used_Dire_Lute","LOCALS",1)
THEN
	RESPONSE #100                                                            
		SetGlobal("gr_Used_Dire_Lute","LOCALS",0)                                            
END