The transformer model listing:

.SUBCKT XfmrPC30-HF 1 2 3 4
*TDK, UU/UI Ferrite (TDK), PC30-HF-100C, UU17
** ** ** **
Rdc1 N41 N61 34.57m
Lmag N41 2 100H ;affects LF response
Rcore N41 2 1meg ;core loss
Rac1 N61 1 0.3
Lac1 N61 1 31.6m
** ** ** **
L12 N41 in2 0.5H ;affects HF response
C1_2 in2 2 6p
C2_23 2 4 200p
C3_23 2 N42 -7p
Efwd2 N82 4 in2 2 0.1 ;turns ratio
Vsens2 N82 N42
Ffbk2 in2 2 Vsens2 0.1 ;turns ratio
Rdc2 N42 N62 1.321m
Rac2 N62 3 21.87m
Lac2 N62 3 23n
.ENDS

The 12AX7 model:

.SUBCKT 12AX7 1 2 3 ; P G C; NEW MODEL
+ PARAMS: MU=100 EX=1.4 KG1=1060 KP=600 KVB=300 RGI=2000
+ CCG=2.3P CGP=2.4P CCP=.9P ; ADD .7PF TO ADJACENT PINS; .5 TO OTHERS.
E1 7 0 VALUE=
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS